2.0.0-rc (#9)

### Issues

* \#1 \[bug\] Unable to mount S3 due to 'item_not_found' exception
* \#2 Require bucket name for S3 mounts
* \#3 \[bug\] File size is not being updated in S3 mount
* \#4 Upgrade to libfuse-3.x.x
* \#5 Switch to renterd for Sia support
* \#6 Switch to cpp-httplib to further reduce dependencies
* \#7 Remove global_data and calculate used disk space per provider
* \#8 Switch to libcurl for S3 mount support

### Changes from v1.x.x

* Added read-only encrypt provider
  * Pass-through mount point that transparently encrypts source data using `XChaCha20-Poly1305`
* Added S3 encryption support via `XChaCha20-Poly1305`
* Added replay protection to remote mounts
* Added support base64 writes in remote FUSE
* Created static linked Linux binaries for `amd64` and `aarch64` using `musl-libc`
* Removed legacy Sia renter support
* Removed Skynet support
* Fixed multiple remote mount WinFSP API issues on \*NIX servers
* Implemented chunked read and write
  * Writes for non-cached files are performed in chunks of 8Mib
* Removed `repertory-ui` support
* Removed `FreeBSD` support
* Switched to `libsodium` over `CryptoPP`
* Switched to `XChaCha20-Poly1305` for remote mounts
* Updated `GoogleTest` to v1.14.0
* Updated `JSON for Modern C++` to v3.11.2
* Updated `OpenSSL` to v1.1.1w
* Updated `RocksDB` to v8.5.3
* Updated `WinFSP` to 2023
* Updated `boost` to v1.78.0
* Updated `cURL` to v8.3.0
* Updated `zlib` to v1.3
* Use `upload_manager` for all providers
  * Adds a delay to uploads to prevent excessive API calls
  * Supports re-upload after mount restart for incomplete uploads
  * NOTE: Uploads for all providers are full file (no resume support)
    * Multipart upload support is planned for S3

Reviewed-on: #9

3rd_party/winfsp-2.0/bin/diag.bat

@@ -0,0 +1,54 @@
+@echo off
+
+setlocal
+setlocal EnableDelayedExpansion
+
+REM Determine the SxS (side-by-side) identifier.
+set SxsDir=
+set RegKey="HKLM\SOFTWARE\WinFsp"
+set RegVal="SxsDir"
+reg query !RegKey! /v !RegVal! /reg:32 >nul 2>&1
+if !ERRORLEVEL! equ 0 (
+    for /f "tokens=2,*" %%i in ('reg query !RegKey! /v !RegVal! /reg:32 ^| findstr !RegVal!') do (
+        set SxsDir=%%j
+    )
+)
+set SxsSuffix=
+if defined SxsDir (
+    set SxsSuffix=!SxsDir:*SxS\sxs.=!
+    if !SxsSuffix:~-1!==\ set SxsSuffix=!SxsSuffix:~0,-1!
+    set SxsSuffix=+!SxsSuffix!
+)
+
+echo WINFSP FSD
+sc query WinFsp!SxsSuffix!
+sc qc WinFsp!SxsSuffix!
+sc sdshow WinFsp!SxsSuffix!
+echo.
+echo.
+
+echo WINFSP DLL
+reg query HKLM\SYSTEM\CurrentControlSet\Control\NetworkProvider\Order
+reg query HKLM\SYSTEM\CurrentControlSet\Services\WinFsp.Np\NetworkProvider
+reg query HKLM\SYSTEM\CurrentControlSet\Services\EventLog\Application\WinFsp
+echo.
+
+echo WINFSP LAUNCHER
+sc query WinFsp.Launcher
+sc qc WinFsp.Launcher
+sc sdshow WinFsp.Launcher
+echo.
+echo.
+
+echo WINFSP REGISTRY
+reg query HKLM\SOFTWARE\WinFsp /s /reg:32
+echo.
+
+echo FILE SYSTEM FILTERS (REQUIRES ADMINISTRATOR)
+fltmc filters
+echo.
+echo.
+
+echo OS INFORMATION
+systeminfo
+echo.

3rd_party/winfsp-2.0/bin/fsreg.bat

@@ -0,0 +1,42 @@
+@echo off
+
+setlocal
+setlocal EnableDelayedExpansion
+
+set RegKey=HKLM\Software\WinFsp\Services
+
+if not X%1==X-u (
+	set unreg=0
+
+	if not X%1==X set fsname=%1
+	if not X%2==X set fsexec="%~f2"
+	if not X%3==X set fscmdl=%3
+	if not X%4==X set fssecu=%4
+
+	if X!fscmdl!==X goto usage
+	if not exist !fsexec! goto notfound
+
+	reg add !RegKey!\!fsname! /v Executable /t REG_SZ /d !fsexec! /f /reg:32
+	reg add !RegKey!\!fsname! /v CommandLine /t REG_SZ /d !fscmdl! /f /reg:32
+	reg add !RegKey!\!fsname! /v JobControl /t REG_DWORD /d 1 /f /reg:32
+	if not X!fssecu!==X reg add !RegKey!\!fsname! /v Security /t REG_SZ /d !fssecu! /f /reg:32
+) else (
+	set unreg=1
+
+	if not X%2==X set fsname=%2
+
+	if X!fsname!==X goto usage
+
+	reg delete !RegKey!\!fsname! /f /reg:32
+)
+
+exit /b 0
+
+:notfound
+echo executable !fsexec! not found >&2
+exit /b 2
+
+:usage
+echo usage: fsreg NAME EXECUTABLE COMMANDLINE [SECURITY] >&2
+echo usage: fsreg -u NAME >&2
+exit /b 2